*
*
*	PAUSE.ASM - Pause utiity for use with SUBMIT files.
*
*	From BYTE article Mar 85 issue Page 416
* 	Entered 15 Mar 85 GLH:W6BSK
*

*
*	Equ tables
*

boot	equ	0000h	; warm boot address
bdos	equ	0005h	; standard BDOS call address
bell	equ	0007h	; bell call
lf	equ	000ah	; line feed
cr	equ	000dh	;carriage return

	org	100h	

start:	
	mvi	c,9	; call the print string function
	lxi	d,msg1
	call	bdos
	mvi	c,1	; call the console input function
	call	bdos
	cpi	'A'	; abort the program?
	jz	killit	;yea, verily.
	mvi	c,9	; no, continue with batch
	lxi	d,msg2
	call	bdos
	jmp     boot	; do a warm boot (continue $$$.sub)

killit:
      	lxi	d,fcblock	;use our local variety
	mvi	c,19		;call delete-file function
	call	bdos
	mvi	c,9
	lxi	d,msg3		;and tell about it.
	call	bdos
	jmp	boot		;exit to CP/M

fcblock:   db	1		; drive A:
	   db	'$$$     SUB'	;this is the processor file
	   db	24		;and this rounds out the fcb

msg1:	   db   cr,lf,bell
	   db	'Enter A to abort the batch,'
	   db   cr,lf,'any other key to resume. $'
msg2:	   db   cr,lf,bell    
	   db	'Resuming batch processing...',cr,lf,'$'
msg3:	   db	cr,lf,bell     
	   db	'Batch process ABORTED...',cr,lf,bell,'$'

	   end  start