0 '	Satellite Location Program

 
5 '	For MBASIC 5.x
6 '
10 '	This Program Will Print The "Elevation Angle"
11 '	And The "Azimuth Angle" To Locate Various Geo-
12 '	Synchronous Earth Satellites.
13 '
14 '	Satellite Names and Longitudes are contained in Data Statements.
15 '	Enter Your Location Name and Coordinates in the First Data Statement
16 '
17 '	Change PRINT Statements To LPRINT For Hard Copy.
99 '

	<Some Initial Values>

 
100 PI = 3.14159
110 A$ = " at ##.## N. Latitude, ###.## W. Longitude"
120 B$ = "Satellite        Satellite       Elevation       Antenna"
130 C$ = "Name             Longitude       Angle           Azimuth"
140 D$ = "\              \ ###.#           ##.##           ###.##"
199 '

	<Some Variable Definitions>

 
200 '	RADIANS = Angle in Radians
210 '	DEGREES = Angle in Degrees
220 '	SITE.LATITUDE = Site Latitude in Degrees
230 '	SITE.LONGITUDE = Site Longitude in Degrees
240 '	SAT.LONGITUDE = Satellite Longitude in Degrees
250 '	ELEVATION = Antenna Elevation Above Horizon
260 '	AZIMUTH = Antenna Azimuth From True North
999 '

	<Get Site Data and Print Header>

 
1000 READ SITE.NAME$,SITE.LATITUDE,SITE.LONGITUDE: GOSUB 5000
1999 '

	<Main Module>

 
2000 READ SAT.NAME$,SAT.LONGITUDE
2010 IF SAT.LONGITUDE THEN GOSUB 7000 ELSE PRINT: END
2020 PRINT USING D$;SAT.NAME$,SAT.LONGITUDE,ELEVATION,AZIMUTH
2030 GOTO 2000
4999 '

	<Print Page Header>

 
5000 PRINT SITE.NAME$;: PRINT USING A$;SITE.LATITUDE,SITE.LONGITUDE
5010 PRINT: PRINT B$: PRINT C$: PRINT
5020 RETURN
6999 '

	<Computation Subroutine>

 
7000 DEGREES = SAT.LONGITUDE - SITE.LONGITUDE: GOSUB 8010: C = RADIANS
7010 DEGREES = SITE.LATITUDE: GOSUB 8010: X = RADIANS
7020 RADIANS = ATN(TAN(C)/SIN(X)): GOSUB 8000
7030 AZIMUTH = 180 + DEGREES
7040 A = ((COS(C)*COS(X)) - .15126): B = SIN(C)/SIN(RADIANS)
7050 RADIANS = ATN(A/B): GOSUB 8000: ELEVATION = DEGREES
7060 RETURN
7999 '

	<Conversion Routines>

 
8000 DEGREES = (RADIANS*360)/(2*PI): RETURN
8010 RADIANS = (DEGREES*2*PI)/360: RETURN
8999 '

	< Site Name, Site N. Latitude, W. Longitude >

 
9000 DATA "YOUR TOWN, USA",47.63,117.63
9010 '

	< Satellite Name,Satellite Longitude,... >

 
9020 DATA N/A,70,GALAXY G2,74,WESTAR 1&2,79,SATCOM F4,83,COMSTAR 3,87
9030 DATA WESTAR 3,91,COMSTAR 2,95,WESTAR 4,99,ANIK D1,104,ANIK B,109
9040 DATA ANIK A3/A2,114,ANIK C3,117.5,SATCOM F2,119,WESTAR 5,123.5
9050 DATA COMSTAR D4,127,SATCOM F3,131,GALAXY 1,134,SATCOM F1,135
9055 DATA SATCOM 5,139,N/A,140
9060 '	( More data Statements as Required )

 
9999 DATA NONE,0,	( Must Be Last Data Statement )
 DATA SATCOM 5,139,N/A,140
9060 '	( More data Statements as Required )

 
9999