;MODEM CONTROL PROGRAM BY DALE HEATHERINGTON
;	4/4/77
;	ENTERED BY R.J.S.	01/01/78
;
;	MODIFIED BY DAVE JAFFE
;	FOR:	BDOS CALLS
;		RETURN TO CP/M ON CONTROL C
;	MODS FOR J A STARK SYSTEM (Switch port & User I/O )
;	4/13/79 -4/24/79
;Further mods 5/20/79 - main loop ala Hayes vs Link
;	Merge with link78 & eol to 00  4/15/79
; MORE BY JAS 30-AUG-79
;
; ON INPUT SYSTEMS EXPECT:
; ATS: CR,00,00,LF,CTL-Q,INPUT,CR
; CMS: CR,LF,CTL-S,'.',CTL-Q,INPUT,CR
; UNIX: CR,01,01,01,01,01,LF,INPUT,CR  (EX IS DIFFERENT)
;
;
;MODEM CONTROL BYTES
ORIG300	EQU	5	;300 BPS ORIGINATE
ANSW300	EQU	1	;300 BPS ANSWER
ORIG110	EQU	4	;110 BPS ORIGINATE
ANSW110	EQU	0	;110 BPS ANSWER
OFFHOOK	EQU	80H	;OFF HOOK MASK
ONHOOK	EQU	7FH	;ON HOOK MASK
TXE	EQU	2	;XMTR ON MASK
TXOFF	EQU	0FDH	;XMTR OFF MASK
WORD	EQU	1FH	;8 BITS, NO PARITY, 2 STOP BITS
;
;PORT ASSIGNMENTS
;Note the next 3 are repeated with different names
;in the LINK78 equates
;
;
DATA	EQU	80H	;MODEM DATA I/O PORT
STAT 	EQU	DATA+1	;STATUS PORT
MODE	EQU	DATA+2	;MODE CONTROL PORT
;
;	SYSTEM EQUATES
BDOS	EQU	5
TOM	EQU	0C5H	;top of memory (page) for 56K CP/M
;
	ORG	100H

;	This module from LINK78.ASM to lib & has equates
;	4/15/79 J A STARK
;         LINK - SUPPORT COMMUNICATIONS LINK WITH CYBER 
; 
;         L.E. HUGHES     EDCAM     JULY, 1977
  
; mods by J A STARK  Dec. 1978 for timesharing & HytypeII printer
;routines for  CMS added 12/29/78
;	HYTYPE is now in ROM at F040H 4/15/79
;         BDOS ENTRY POINT AND FUNCTION CODES 
  
;BDOS is EQU in DCHAYES.ASM
 OFFC     EQU    15             ;OPEN FILE
 CFFC     EQU    16             ;CLOSE FILE 
 DFFC     EQU    19             ;DELETE FILE
 RRFC     EQU    20             ;READ RECORD
 WRFC     EQU    21             ;WRITE RECORD 
 MFFC     EQU    22             ;MAKE FILE
ROMPRT	EQU	0F040H	;HYTYPE in ROM
;	Input CHAR MUST BE IN C
CRPOS	EQU	0DE98H
CRCNT	EQU	0DE9AH
BHB	EQU	0DE9CH

  
;         DEFAULT FCB AND FIELD DEFINITIONS 
  
 FCB      EQU    5CH
 FN       EQU    1              ;FILE NAME FIELD (REL)
 FT       EQU    9              ;FILE TYPE FIELD (REL)
 NR       EQU    32             ;NEXT RECORD FIELD (REL)
 DBUF     EQU    80H            ;DEFAULT DISK BUFFER ADDRESS
  
;         ASCII CONTROL CHARACTERS
  
 LF       EQU    012Q           ;LINE FEED
 CR       EQU    015Q           ;CARRIAGE RETURN
 DEL      EQU    177Q           ;DELETE 
  
;         I/O PORT ADDRESSES
  
 COND     EQU     01H           ;CONSOLE DATA PORT
 CONS     EQU    000H           ;CONSOLE STATUS PORT
 MODD     EQU     80H           ;MODEM DATA PORT
 MODS     EQU     81H           ;MODEM STATUS PORT
 ;CONT    EQU    018H           ;SIO CONTROL PORT FOR MODEM
  
BRK	EQU	09H	;hardware 240ms break function port

;         STATUS PORT BIT DEFINITIONS 
  
MTBE     EQU    02H           ;TRANSMIT BUFFER READY FOR ANOTHER BYTE 
MRDA     EQU    01H           ;READ DATA AVAILABLE
CTBE     EQU    80H    ;CONSOLE WRITE
CRDA     EQU    01H   ;CONSOLE KEYBD
;console data ready low, modem high

;SENSE SWITCH 8 Port 9 IS USED FOR SPEED SELECT.UP IS 300 BAUD
;DOWN IS 110 BAUD.
;
;SENSE SWITCH 1 	-At present Stark's switches are inverted
; UP WILL SUPRESS ECHO CHAR TO CONSOL ON DATA TRANSMISSION
;sens.sw. 2=1 supplies LF after CR. If =0 then waits for called system LF (usual case)
;sens.sw. 3=1 will block all CTL-CHAR in PCC subrout.
;Must be =0 for normal operation
;sens. sw. 4=1 for full duplex modem, =0 for half duplex
;(0= no char. echo back to calling system)
;SENS. SW. 5=1 FOR SAVE OF KEYBOARD INPUT TO MODEM. 0= NO SAVE OF KEYBOARD.

;
START	JMP	SIGNON
OUTPUT	JMP	USEROT	;JUMP TO USER OUT ROUTINE
INPUT	JMP	USERIN	;JUMP TO USER IN ROUTINE
INSTAT	JMP	USERST	;JUMP TO USER CONSOLE STATUS
			;CHECK ROUTINE. RETURNS 'FF'
			;IF A BYTE IS WAITING OR
			; '00' IF NOT.
;
;THIS ROUTINE LOOPS UNTIL THE LINE RINGS OR A
;CONTROL B IS TYPED ON THE CONSOLE.
;
SIGNON:	LXI 	SP,STKTOP
	LXI	H,SIGN	;POINT TO SIGNON MESSAGE
	CALL	PRINTM
	MVI	A,0
	OUT	STAT	;CLEAR MODEM REGISTER
RINGCK:	
	CALL	INSTAT	;GET CONSOLE STATUS
	CNZ	INPUT	;GET BYTE IF READY
	CPI	2	;CHECK FOR "STX" OR CONTROL B
	JZ	MAKCALL	;GOTO ORIG ROUTINE
	CPI	3	;CONTROL C?
	JZ	0	;BACK TO CP/M
	IN	STAT	;GET MODEM STATUS
	ANI	80H	;ISOLATE RING DET. BIT
	JNZ	RINGCK	;LOOP UNTIL IT GOES LOW
ANCALL:
	CALL	AN110	;SET TO ANSWER MODE
	CALL	OFFHK	;GO OFFHOOK
	LDA	MDBYTE	;GET MODE
	ORI	TXE
	STA	MDBYTE
	OUT 	MODE	;TURN ON XMITTER
	LXI	H,CALLIN	;Point to CALLIN MSG
	CALL	PRINTM	;print it
	JMP	CARR-3	;JMP TO DATA HANDLING ROUTINE
MAKCALL:
	LXI	SP,STKTOP
	CALL	OR110	;SET TO ORIGINATE MODE
	LXI	H,MNUM	;POINT TO STRING "NUMBER"
	CALL	PRINTM	;PRINT THE STRING
	CALL	DIAL	;GET AND DIAL A PHONE NUMBER
	LXI	D,400	;SETUP FOR A 20 SECOND DELAY
CARR:	CALL	SPEED	;SET SPEED
	IN	STAT	;LOOK FOR A CARRIER
	ANI	40H	;ISOLATE CARRIER BIT
	JNZ	CONNECT	;JUMP IF TRUE
	CALL	DELAY	;WAIT 50 MS
	DCX	D	;COUNT IT
	MOV	A,D	;TEST FOR D&E =0
	ORA	E
	JNZ	CARR	;LOOP IF NOT TIMED OUT
	LXI	H,NOASW	;POINT TO STRING "NO ANSWER"
	CALL	PRINTM	;PRINT THE STRING
	JMP	EOT	;DISCONNECT
CONNECT:
	LDA	MDBYTE	;GET MODE
	ORI	TXE	;TURN ON XMTTR
	OUT	MODE
	STA	MDBYTE
	ANI	4	;ISOLATE ORIG/ANSW BIT
	CZ	SAB	;SEND ANSWER/BACK
TTY:	IN	STAT	;GET MODEM STATUS
	ANI	40H	;ISOLATE CARRIER DETECT BIT
	JNZ	OK	;
	LXI	H,LOSTC	;POINT TO STRING "LOST CARRIER"
	CALL	PRINTM	;PRINT THE STRING
	JMP	EOT
OK:	CALL 	SPEED	;SET SPEED

;from lnk2.lib
 LINK2:   XRA    A              ;CLEAR CHAR BUFFERS 
          STA    INCH 
          STA    OUTCH
          STA    FLAG           ;CLEAR TEXT SAVE FLAG 
          LXI    H,TBUF         ;SET PTR TO TBUF
          SHLD   PTR
          LXI    H,0            ;SIZE = 0 
          SHLD   SIZE 
          CALL   WCCR           ;WRITE CR/LF TO CONSOLE 
   lxi h,RDY
   call wcs
	CALL	WCCR		;cr, lf
;Find out if calling (IBM) CMS, set flag
	LXI	H,CMS	;send message
	CALL	WCS
	CALL	RCC	;get ans. from console
	CALL	WCC	;echo
	CPI	'Y'
	JZ	SETFLG
	CPI	'Y'+20H	;U/L case
	JZ	SETFLG
	XRA	A	;not cms, flg=0
	STA	CMSFLG	;is in data area
	CALL	WCCR
	JMP	LINK3
SETFLG:	MVI	A,1	;is CMS, flg=1
	STA	CMSFLG
	CALL	WCCR
	JMP	LINK3
RDY:	DB	'READY ',0
CMS:	DB	13,10,10,'  SENS. SW. 3=1 for block of CTL-CHAR in PCC subrout.',13,10
	DB	'CMS ? Y/N ',0
SYS:	DB	'SIGN ON ANOTHER SYSTEM ?',0  
CALLIN:	DB	13,10,'CALL COMING IN',13,10,0
SPDCAR:	DB	80H

;         MAIN LOOP 
  
LINK3:	LXI	H,SPDCAR	;point to count store
	DCR	M	;each 256 passes check speed & carrier
	JNZ	OK2
	CALL SPEED
	IN	STAT
	ANI	40H
	JNZ	OK2
	LXI	H,LOSTC
	CALL	PRINTM
	JMP	EOT
OK2:	IN	STAT	;get modem status
	ANI	1	;check for data byte
	JZ	C3	;JUMP IF NO DATA
GETC:	IN	DATA	;GET A MODEM BYTE
	ANI	7FH	;KILL PARITY
	CPI	4	;CHECK FOR EOT
	JZ	EOT1	;
	JC	OK2	;SKIP IF <CTL-D
	CPI	5	;CHECK FOR ENQ
	CZ	SAB	;SEND ANSWERBACK IF TRUE
	CPI	'Q'-100Q	;CTL-Q UPSETS CRT
	JZ	OK2	;DISCARD IT BY JUMP TO MAIN LOOP
	CPI	'S'-100Q	;DISCARD CTL-S
	JZ	OK2
	MOV	C,A
;ADDED 5/20/79
	CALL	SAVE
	IN	09H	;GET SENS. SW
	ANI	08H	;SENS SW 4=1=FULL DUPLEX
	MOV	A,C	;FLAGS UNAFFECTED
	JZ	C2
	CALL	WMC	;echo char thru modem
;
C2:	CALL	WCC	;PRINT THE CHAR
;
C3:	CALL	USERST	;check if char from console
	ANA	A	;set flags
	JZ	LINK3	;jmp if no data
	IN	1	;KEYBD
	ANI	7FH	;KILL PARITY
	MOV	C,A	;save A
;ADDED 11/30/78
	IN	09H	;READ SENS SW 5
	ANI	10H	;1=SAVE KEYBOARD DATA
	MOV	A,C	;REPLACE A, FLAGS SAME
	JZ	C4	;NO, GO ON
	CALL	SAVE	;YES,DO IT

;
C4:	IN	09H	;check sens sw. 3 - no CTL-CHAR
	ANI	04H
	MOV	A,C	;replace A, flags unchanged
	JNZ	LNK	;no CTL codes to PCC until SW. 3=0
	CPI	40Q	;comp. with space
	CC	PCC	;if less, must be ctl-char
	JC	LINK3	;jump if PCC handled CTL-CHAR
LNK:	MOV	C,A	;data in C for TRANS or OUTPUT
	CALL	TRANS
	JMP	LINK3
;
  
;         PCC - PROCESS CONTROL CHARACTER 
;CTL-X equal return to CP/M
;CTL-S = send text file from disk to modem
;CTL-R = save text from modem to buffer
;CTL-Q = stop saving to buffer &
;start writing to disk, then cleat buffer
;CTL-P = stop savaing, print buff., then clear
;CTL-T=Set up for another system
;CTL-U=Stop sending file to modem & close
;ESC=Thru OUT 09H strobe 240ms break (space) sent both from hayes modem & port  8 (acoustic modem)
  
 PCC:     CPI    'X'-100Q       ;JUMP IF NOT CONTROL-X
          JNZ    PCC1 
	JMP	EOT	;Terminate transmission, CTL-C to ret to CP/M
 PCC1:    CPI    'S'-100Q       ;JUMP IF NOT CONTROL-S
          JNZ    PCC2 
          CALL   STF            ;SEND TEXT FILE TO MODEM
          STC                   ;TELL LINK TO IGNORE THIS CHARACTER 
          RET 
 PCC2:    CPI    'R'-100Q       ;JUMP IF NOT CONTROL-R
          JNZ    PCC3 
          MVI    A,1            ;TURN ON TEXT SAVE FLAG 
          STA    FLAG 
          STC 
          RET 
 PCC3:    CPI    'Q'-100Q       ;JUMP IF NOT CONTROL-Q
          JNZ    PCC4 
          XRA    A              ;TURN OFF TEXT SAVE FLAG
          STA    FLAG 
          CALL   WTB            ;WRITE TEXT BUFFER TO DISK
          LXI    H,TBUF         ;CLEAR TEXT BUFFER
          SHLD   PTR
          LXI    H,0
          SHLD   SIZE 
          STC 
          RET 
PCC4:	CPI	'P'-100Q	;stop saving, print, clear
	JNZ	PCC5
	XRA	A	;turn off save flag
	STA	FLAG
	CALL	WPB	;buff. to printer
	LXI	H,TBUF
	SHLD	PTR
	LXI	H,0
	SHLD	SIZE
	STC
	RET
;Break function on escape key
PCC5:	CPI	1BH	;escape
	JNZ	PCC6
	OUT	BRK
	STC
	RET
PCC6:	CPI	'T'-100Q
	JNZ	PCC7
	LXI	H,SYS	;send new system msg.
	CALL	WCS
	JMP	CONNECT	;restart just below carrier detect
PCC7:
	STC
	CMC	;let link handle all other ctl codes
	RET

;         STF - SEND TEXT FILE (TO MODEM) 
  
 STF:     CALL   GFN            ;GET NAME OF DISK FILE TO SEND
          JC     STF6           ;JUMP IF FILE NAME ERROR
          CALL   OPEN           ;TRY TO OPEN SPECIFIED FILE 
          CPI    255            ;JUMP IF FILE NOT FOUND 
          JZ     STF7 
          XRA    A              ;ELSE REWIND FILE AND GET ON WITH IT
          STA    FCB+NR 
 STF1:    CALL   READ           ;READ NEXT RECORD INTO DBUF 
          CPI    1              ;JUMP IF END-OF-FILE
          JZ     STF5 
          LXI    H,DBUF         ;POINT TO DISK BUFFER 
          MVI    C,128
 STF2:    MOV    A,M            ;FETCH NEXT CHAR FROM DBUF
          INX    H
          CPI    'Z'-100Q       ;JUMP IF END-OF-FILE CHARACTER
          JZ     STF5 
	CPI	LF		;SCREEN OUT LF HERE
	JZ	STF4
	CPI	'Q'-100Q	;ignore CTL-Q (from CMS)
	JZ	STF4
	CPI	'S'-100Q	;CTL-S
	JZ	STF4		;IGNORE IT
	CALL	WMC		;WRITE MODEM CHAR
	CPI	'I'-100Q	;tab
	CZ	TAB	;send 4 spaces
          CALL   WCC            ;WRITE CHARACTER TO CONSOLE 
	MOV	B,A	;save A
	CALL	INSTAT	;consol char?
	JZ	STF9
	CALL	INPUT	;get it
	CPI	'U'-100Q	;stop sending file & close
	JZ	STF5
STF9:	MOV	A,B	;replace A
         CPI    CR             ;JUMP IF NOT CARRIAGE RETURN
          JNZ    STF4 
;Check if CMS
	LDA	CMSFLG	;=0 if not CMS
	ORA	A
	JZ	STF3	;A=0 so use reg. format
	MVI	A,10	;LF
	CALL	WCC
CMS1:	IN	MODS	;modem status
	ANI	MRDA
	JZ	CMS1	;not yet
	IN	MODD	;get byte
	ANI	7FH	;strip bit 7
	CPI	'.'	; CMS ENTRY FLAG
	JNZ	CMS1	;try again
CMS2:	IN	MODS
	ANI	MRDA
	JZ	CMS2
	IN MODD		;TO CATCH CTL-Q & DISCARD
	MVI	A,'.'
	CALL	WCC
	JMP	STF4
;Program will hang-up here if system does not supply LF after entered CR !!!
; OK on UNIX, (IBM) ATS
STF3:	IN	09	;Sens.sw.
	ANI	02	;sw 2
	JZ	STF8	;let system do it
	MVI	A,0AH	;LF
	CALL	WMC	;write modem char
	CALL	WCC	;WRITE console char
	JMP	STF4	;get on with it

 STF8:    CALL   RMC            ;AWAIT LINE FEED FROM MODEM 
         CPI    LF 
         JNZ    STF3 
         CALL   WCC            ;ECHO LINE FEED TO CONSOLE
 STF4:    DCR    C              ;LOOP THRU REST OF DBUF 
          JNZ    STF2 
          JMP    STF1           ;GO GET NEXT RECORD FROM DISK 
 STF5:    CALL   CLOSE          ;CLEAN UP ACT AND GO HOME 
          RET 
 STF6:    LXI    H,STFS1        ;PRINT 'FILE NAME ERROR'
          CALL   WCS
          RET 
 STF7:    LXI    H,STFS2        ;PRINT 'FILE NOT FOUND' 
          CALL   WCS
          RET 
  
TAB:	MVI	A,' '	;space
	CALL	WCC
	CALL	WCC
	CALL	WCC
	RET

 STFS1:   DB     'FILE NAME ERROR',CR,LF,0
 STFS2:   DB     'FILE NOT FOUND',CR,LF,0 
  
;         SAVE - SAVE CHAR IN TEXT BUFFER IF FLAG ON
; 
;         ENTRY CONDITIONS
;            A - CHARACTER TO SAVE
  
 SAVE:    PUSH   PSW
          LDA    FLAG 
          ORA    A
          JNZ    SAVE1
          POP    PSW
          RET 
 SAVE1:   POP    PSW
          PUSH   H
          LHLD   PTR
          MOV    M,A
          INX    H
;subrout. to find top of mem. before CCP
	MOV	B,A	;save A
	MVI	A,TOM	;Top of mem. page (56K)
	CMP	H
	CZ	EOS	;yes, send msg. & quit!
	MOV	A,B	;replace A
;
          SHLD   PTR
          LHLD   SIZE           ;SIZE = SIZE + 1
          INX    H
          SHLD   SIZE 
          POP    H
          RET 
  
; EOS End of save space
EOS:	LXI	H,EOSMSG	;see data area
	CALL	WCS	;send msg.
	XRA	A	;zero A
	STA	FLAG	;to FLAG
	MVI	C,7	;CTL-G OR BELL
	CALL	USEROT	;SEND IT
	RET

; WPB - Write text buffer to printer

WPB:	LHLD	SIZE
	MOV	A,L
	ORA	H
	JZ	WTB5	;Print 'buff. M.T. & RET
	LHLD	SIZE
	XCHG	;DE=buff. size
	LXI	H,TBUF
WPB2:	MOV	C,M	;data in C, CP/M standard
	INX	H
	CALL	ROMPRT	;	Now in ROM at F040H
	;HytypeII printer routine
	DCX	D
	MOV	A,D
	ORA	E
	JZ	WTB5	;exit
	JMP	WPB2

;         WTB - WRITE TEXT BUFFER TO DISK 
  
 WTB:     LHLD   SIZE           ;JUMP IF TEXT BUFFER EMPTY
          MOV    A,L
          ORA    H
          JZ     WTB5 
          CALL   GFN            ;GET FILE NAME
          JC     WTB6           ;JUMP IF FILE NAME ERROR
          CALL   DELT           ;DELETE OLD FILE, IF ANY
          CALL   MAKE           ;MAKE NEW FILE
          XRA    A              ;REWIND FILE
          STA    FCB+NR 
          LHLD   SIZE           ;DE = TBUF SIZE 
          XCHG
          LXI    H,DBUF         ;TOP OF STACK POINTS TO DBUF
          PUSH   H
          LXI    H,TBUF         ;HL POINTS TO TBUF
 WTB1:    MVI    C,128          ;DISK BUFFER SIZE 
 WTB2:    MOV    A,M            ;FETCH NEXT BYTE OF TBUF
          INX    H
          XTHL
          MOV    M,A            ;STORE IN DBUF
          INX    H
          XTHL
          DCX    D              ;SIZE = SIZE - 1
          MOV    A,D            ;EXIT LOOP IF SIZE = 0
          ORA    E
          JZ     WTB3 
          DCR    C              ;LOOP UNTIL DBUF FULL 
          JNZ    WTB2 
          CALL   WRITE          ;WRITE FULL DBUF TO DISK
          XTHL                  ;TOP OF STACK POINTS TO DBUF
          LXI    H,DBUF 
          XTHL
          JMP    WTB1           ;LOOP UNTIL END OF TBUF 
 WTB3:    POP    H              ;HL POINTS TO CURRENT PLACE IN DBUF 
 WTB4:    MVI    M,'Z'-100Q     ;STORE EOF CODE 
          INX    H
          DCR    C              ;LOOP THRU REST OF DBUF 
          JNZ    WTB4 
          CALL   WRITE          ;WRITE LAST SECTOR TO DISK
          CALL   CLOSE          ;CLEAN UP ACT AND GO HOME 
	LXI	H,WTBS3	;print 'BUFFER WRITTEN TO DISK'
	CALL	WCS
          RET 
 WTB5:    LXI    H,WTBS1        ;PRINT 'TEXT BUFFER EMPTY'
          CALL   WCS
	XRA	A
	STA	BHB	;set up print for restore
; (see end of HYTYPE routine)
          RET 
 WTB6:    LXI    H,WTBS2        ;PRINT 'FILE NAME ERROR'
          CALL   WCS
          RET 
 WTBS1:   DB     'TEXT BUFFER EMPTY',CR,LF,0
 WTBS2:   DB     'FILE NAME ERROR',CR,LF,0
WTBS3:	DB	'BUFFER WRITTEN TO DISK',CR,LF,0
WTBS4:	DB	'FILE CLOSED',CR,LF,0
WTBS5:	DB	'FILE OPENED',CR,LF,0
  
;         WCS - WRITE CONSOLE STRING
  
; 
;         ENTRY CONDITIONS
;            HL - POINTS TO STRING (TERM BY ZERO BYTE)
  
 WCS:     MOV    A,M
          INX    H
          ORA    A
          RZ
          CALL   WCC
          JMP    WCS
  
;         WCCR - WRITE CONSOLE CARRIAGE RETURN (AND LINE FEED)
  
 WCCR:    MVI    A,CR 
          CALL   WCC
          MVI    A,LF 
  
;         WCC - WRITE CONSOLE CHARACTER 
; 
;         ENTRY CONDITIONS: 
;            A - CHARACTER TO WRITE 
  
 WCC:     PUSH   PSW
          IN     CONS 
          ANI   CTBE
          JNZ     $-4
          POP    PSW
          OUT    COND 
          RET 
  
;         RCS - READ CONSOLE STRING (WITH ECHO) 
; 
;         EXIT CONDITIONS 
;            B - NUMBER OF CHARACTERS READ (<255) 
;            HL - POINTS TO LAST CHAR STORED (CR) 
  
 RCS:     LXI    H,IBUF 
          MVI    B,0
 RCS1:    CALL   RCC            ;READ NEXT CHAR FROM CONSOLE
          CPI    DEL            ;JUMP IF NOT DEL
          JNZ    RCS2 
          INR    B              ;IGNORE DEL IF IBUF ALREADY EMPTY 
          DCR    B
          JZ     RCS1 
          DCX    H              ;ELSE DISCARD LAST CHAR 
          MOV    A,M            ;ECHO DISCARDED CHAR TO CONSOLE 
          CALL   WCC
          DCR    B              ;DECREMENT COUNT
          JMP    RCS1           ;  AND LOOP 
 RCS2:    CPI    'U'-100Q       ;JUMP IF NOT CONTROL-U
          JNZ    RCS3 
          CALL   WCCR           ;ELSE ABORT CURRENT LINE
          JMP    RCS            ;  AND START OVER 
 RCS3:    CALL   WCC            ;ECHO CHAR TO CONSOLE 
          MOV    M,A            ;STORE CHAR IN IBUF 
          INR   B           ;INCREMENT COUNT
          CPI    CR         ;JUMP IF CARRAGE RETURN
         JZ     RCS4 
          INX    H              ;ELSE ADVANCE POINTER 
          JMP    RCS1           ;  AND LOOP 
 RCS4:    MVI    A,LF           ;ISSUE LINE FEED AND RETURN 
          CALL   WCC
          RET 
  
;         RCC - READ CONSOLE CHARACTER
; 
;         EXIT CONDITIONS 
;            A - CHARACTER READ 
  
 RCC:     IN     CONS 
          ANI    CRDA
          JNZ    $-4
          IN     COND 
          ANI    177Q 
          RET 
  
;         WMC - WRITE MODEM CHARACTER 
; 
;         ENTRY CONDITIONS
;            A - CHARACTER TO WRITE 
  
 WMC:     PUSH   PSW
          IN     MODS 
          ANI    MTBE
          JZ     $-4
          POP    PSW
          OUT    MODD 
          RET 
  
;         RMC - READ MODEM CHARACTER
; 
;         EXIT CONDITIONS:
;            A - CHARACTER READ 
  
 RMC:     IN     MODS 
          ANI    MRDA
	JZ	$-4	;jmp if not ready
          IN     MODD 
          ANI    177Q 
          RET 

;	GFN - GET FILE NAME
  
 GFN:     CALL   WCCR 
          LXI    H,GFNS1        ;PRINT 'FILENAME? ' 
          CALL   WCS
          CALL   RCS            ;READ RESPONSE INTO IBUF
          LXI    H,FCB+FN       ;BLANK FILL FN AND FT FIELDS
          MVI    C,11 
 GFN1:    MVI    M,' '
          INX    H
          DCR    C
          JNZ    GFN1 
          LXI    H,IBUF         ;POINT TO INPUT BUFFER
          LXI    D,FCB+FN       ;SCAN OFF FN FIELD
          MVI    C,9
 GFN2:    MOV    A,M            ;FETCH NEXT CHAR FROM IBUF
          INX    H
          CPI    141Q           ;IF LC, CONVERT TO UC 
          JC     $+5
          SUI    40Q
          CPI    CR             ;JUMP IF END OF LINE
          JZ     GFN5 
          CPI    '.'            ;JUMP IF END OF NAME
          JZ     GFN3 
          STAX   D              ;ELSE STORE CHAR IN FN FIELD
          INX    D
          DCR    C              ;LOOP IF 8 OR LESS CHARS SO FAR 
          JNZ    GFN2 
          JMP    GFN6           ;ELSE TAKE ERROR EXIT 
 GFN3:    LXI    D,FCB+FT       ;SCAN OFF FT FIELD
          MVI    C,4
 GFN4:    MOV    A,M            ;FETCH NEXT CHAR FROM IBUF
          INX    H
          CPI    141Q           ;IF LC, CONVERT TO UC 
          JC     $+5
          SUI    40Q
          CPI    CR             ;JUMP IF END OF LINE
          JZ     GFN5 
          STAX   D              ;ELSE STORE CHAR IN FT FIELD
          INX    D
          DCR    C              ;LOOP IF 3 OR LESS CHARS SO FAR 
          JNZ    GFN4 
          JMP    GFN6           ;ELSE TAKE ERROR EXIT 
 GFN5:    STC                   ;CLEAR ERROR FLAG AND RETURN
          CMC 
          RET 
 GFN6:    STC                   ;SET ERROR FLAG AND RETURN
          RET 
  
 GFNS1:   DB     'FILENAME? ',0 
  
;         OPEN - OPEN DISK FILE 
  
 OPEN:    PUSH   H
          PUSH   D
          PUSH   B
          LXI    D,FCB
          MVI    C,OFFC 
          CALL   BDOS 
	LXI	H,WTBS5	;'FILE OPENED' message
	CALL	WCS
          POP    B
          POP    D
          POP    H
          RET 
  
;         READ - READ RECORD FROM DISK FILE 
  
 READ:    PUSH   H
          PUSH   D
          PUSH   B
          LXI    D,FCB
          MVI    C,RRFC 
          CALL   BDOS 
          POP    B
          POP    D
          POP    H
          RET 
  
;         CLOSE - CLOSE DISK FILE 
  
 CLOSE:   PUSH   H
          PUSH   D
          PUSH   B
          LXI    D,FCB
          MVI    C,CFFC 
          CALL   BDOS 
	LXI	H,WTBS4	;'FILE CLOSED' MESSAGE
	CALL	WCS
          POP    B
          POP    D
          POP    H
          RET 
  
;         DELT - DELETE DISK FILE 
  
 DELT:    PUSH   H
	PUSH	D
	PUSH	B
	LXI	D,FCB
	MVI	C,DFFC
	CALL	BDOS
	POP	B
	POP	D
          POP    H
          RET 
  
;         WRITE - WRITE RECORD TO DISK
  
 WRITE:   PUSH   H
          PUSH   D
          PUSH   B
          LXI    D,FCB
          MVI    C,WRFC 
          CALL   BDOS 
          POP    B
          POP    D
          POP    H
          RET 
  
;         MAKE - MAKE NEW DISK FILE 
  
 MAKE:    PUSH   H
          PUSH   D
          PUSH   B
          LXI    D,FCB
          MVI    C,MFFC
          CALL   BDOS 
          POP    B
          POP    D
          POP    H
          RET 
  
;SPEED SELECT ROUTINE
;USES SENSE SWITCH A-15; UP IS 300 BAUD,DOWN IS 110
;
SPEED:	PUSH	B
	LDA	MDBYTE	;GET PRESENT MODE
	MOV	B,A	
	IN	9	;GET SENSE SWITCH
	ANI	80H	
	MOV	A,B
	JZ	S110
	ORI	1	;SET TO 300 BPS
	DB	01H	;*****TRICK*** LXI B (NOP NEXT 2 BYTES)
S110:	ANI	0FEH	;SET TO 110 BPS
	STA	MDBYTE	
	OUT	MODE	;SET MODEM
	POP	B
	RET
;
;PRINTS CHAR ON CONSOLE.CHECKS FOR EOT CHAR
;AND TERMINATES CALL IF TRUE.
;
PRINT:	MOV	A,C	;GET A BYTE
	CPI	4	;CHECK FOR EOT
	JNZ	OUTPUT	;OUTPUT THE BYTE
EOT1:	LXI	H,MEOT	;POINT TO STRING "EOT"
	CALL	PRINTM	;PRINT IT
	MVI	B,10	;SET FOR .5 SEC DELAY
DLY3:	CALL	DELAY
	DCR	B
	JNZ	DLY3	;LOOP FOR .5 SEC
EOT:	LDA	MDBYTE	;GET CURRENT MODE
	ANI	TXOFF	;TURN OFF XMTTR
	ANI	ONHOOK	;DISCONNECT LINE
	OUT MODE
	STA	MDBYTE
	LXI	H,TERM	;POINT TO STRING "TERMINATED"
	CALL	PRINTM	;PRINT IT
	JMP	SIGNON	;BACK TO THE START
;
;
;THIS ROUTINE PRINTS AN ASCII STRING IN MEMORY ON THE CONSOL
;
PRINTM:	MVI	A,0
	MOV	C,M	;GET A BYTE
	CMP	C	;TEST FOR 00 (END OF STRING)
	RZ		;FINISHED
	CALL	OUTPUT	;PRINT IT
	INX	H	;POINT TO NEXT BYTE
	JMP	PRINTM	;LOOP AGAIN
;
;SETS THE MODEM TO ORIGINATE OR ANSWER MODE
;
OR110:	MVI	A,ORIG110	;GET MODE BYTE
	JMP	AN110+2
AN110:	MVI	A,ANSW110	;GET ANSWER MODE BYTE
	STA	MDBYTE	;SAVE IT
	OUT	MODE	;SETUP MODEM
	MVI	A,WORD	;GET WORD FORMAT
	OUT	STAT	;SETUP MODEM
	RET
;
;THIS ROUTINE GETS DIGITS FROM THE CONSOL
;AND STORES THEM IN MEMORY. IT THEN TAKES THE LINE
;OFF HOOK AND DIALS THE DIGITS STORED IN MEMORY.
;IF A '*' APPEARS IN THE DIGIT STRING THE PROGRAM
;PAUSES FOR 2 SECONDS. THIS IS TO WAIT FOR SECOND DIAL
;TONE IN SOME EXCHANGES.
;
DIAL:	CALL	GETNUM	;GET PHONE NUMBER FROM KBD
	CALL	OFFHK	;GO OFFHOOK
	LXI	H,MDIAL	;POINT TO STRING "DIALING--"
	CALL	PRINTM	;PRINT IT
	MVI	B,40	;SETUP FOR 2 SECOND DELAY
WAIT:	CALL	DELAY	;WAIT FOR DIAL TONE
	DCR	B
	JNZ	WAIT
DIAL2	LXI	H,NMBR	;POINT TO PHONE NUMBER
	MOV	A,M	;GET A DIGIT
	CPI	0DH	;CHECK FOR THE END
	RZ
	MOV	C,A	;
	CALL	OUTPUT	;PRINT THE DIGIT TO BE DIALED
	CPI	'*'	;DELAY?
	JNZ	NODLY
	MVI	B,40	;SETUP FOR 2 SECOND DELAY
WAIT2:	CALL	DELAY
	DCR	B
	JNZ	WAIT2
NODLY:	INX	H	;POINT TO NEXT DIGIT
	SUI	30H	;REMOVE ASCII BIAS
	JNZ	NOTZERO	;CHECK FOR A DIGIT "0"
	MVI	A,10	;MAKE A 0 A 10
NOTZERO:
	JC	DIAL2+3	;IF <0 GET NEXT DIGIT
	CPI	11	;CHECK FOR MORE THAN 10
	JNC	DIAL2+3	;IF MORE GET NEXT DIGIT
	CALL	PULSE	;MAKE DIAL PULSES
	JMP	DIAL2+3
;
;THIS SUBROUTINE PULSES THE LINE,
;THE VALUE IN ACC EQUALS THE NUMBER OF
;PULSES OUTPUT.
;
PULSE:	PUSH	PSW
	CALL	ONHK	;GO ONHOOK
	CALL	DELAY	;WAIT 50 MS
	CALL	OFFHK	;GO OFF HOOK
	CALL	DELAY	;WAIT 50 MS
	POP	PSW	;GET DIGIT
	DCR	A	;SUBTRACT 1 FROM DIGIT
	JNZ	PULSE	;ANOTHER PULSE IF NOT ZERO
	MVI	A,10	;SET UP FOR 500 MS DELAY
SPACE:	CALL	DELAY	;WAIT 500 MS
	DCR	A	;
	JNZ	SPACE
	RET		;DIGIT COMPLETE
;
;	THIS ROUTINE WAITS 50 MS BEFORE RETURNING
;
DELAY:	PUSH	H
	PUSH	D
	PUSH	PSW
	CALL	INSTAT
	ORA	A	;SET FLAGS
	CNZ	INPUT	;GET A CONSOL BYTE
	CPI	4	;CONTROL D?
	JZ	EOT1	;ABORT
	POP	PSW
	LXI	D,50
	LXI	H,0
DLYLP:	XTHL		;WAIST TIME FOR DELAY
	XTHL
	DAD	D	;ADD D&E TO H&L
	JNC	DLYLP	;LOOP UNTIL CARRY
	POP	D
	POP	H
	RET
;
;GETS BYTES FROM THE CONSOLE AND STORES THEM IN RAM.
;
GETNUM:	LXI	H,NMBR	;POINT TO BUFFER
	CALL	INSTAT	;GET KBD STATUS
	ANA	A	;SET FLAGS
	JZ	GETNUM+3;LOOP UNTIL KBD IS READY
	CALL	INPUT	;GET A DIGIT
	CPI	4	;CONTROL D
	JZ	SIGNON	;ABORT
	CPI	2	;IS IT A CONTROL B?
	JZ	GETNUM+3;IGNORE GARBAGE CHAR
	CPI	3	;IS IT A CONTROL C?
	JZ	0	;RETURN TO CP/M
	MOV	M,A	;STORE IT
	MOV	C,A	;
	PUSH	PSW	;SAVE ACC FROM VDM ROUTINE
	CALL	OUTPUT	;ECHO THE DIGIT
	POP	PSW	;SAFE AND SOUND
	CPI	0DH	;CHECK FOR ASCII "CR"
	RZ		;DONE IF TRUE
	INX	H	;POINT TO NEXT BUFFER LOC.
	CPI	08H	;BACKSPACE?
	JNZ	GETNUM+3;IF NOT GET NEXT DIGIT
	DCX	H
	DCX	H	;BACKUP POINTER
	JMP	GETNUM+3	;GET NEXT DIGIT
;
;THESE ROUTINES SET THE MODEM FOR "ONHOOK" OR "OFFHOOK"
;
OFFHK:	LDA	MDBYTE	;GET THE CURRENT MODE BYTE
	ORI	OFFHOOK	;SET THE OFF HOOK BIT
	JMP	SETT	
ONHK:	LDA	MDBYTE	;GET CURRENT MODE BYTE
	ANI	ONHOOK	;RESET THE OFF HOOK BIT
SETT:	STA	MDBYTE	;SAVE NEW MODE BYTE
	OUT	MODE	;SET THE MODEM
	RET
;
;THIS SUBROUTINE SENDS THE ANSWER BACK MESSAGE
                ;
SAB:	PUSH	H
	PUSH	D
	PUSH	B
	LXI	D,100H	; 5 sec. delay
SDLY:	CALL	DELAY
	DCX	D
	MOV	A,D
	ORA	E
	JNZ	SDLY
	LXI	H,ANSBK	;POINT TO ANSWER BACK MESSAGE
GAB:	MOV	A,M	;GET A BYTE
	CPI	0	;END?
	JZ	EXIT
	MOV	C,A
	CALL	TRANS	;SEND THE BYTE
	INX	H
	JMP	GAB	;LOOP AGAIN
EXIT:	POP	B
	POP	D
	POP	H
	RET
;
;THIS SUBROUTINE SENDS A BYTE TO THE MODEM
;AND TO THE CONSOL DISPLAY DEVICE.
;
TRANS:	IN	STAT	;SEE IF READY FOR BYTE
	ANI	2
	JZ	TRANS	;LOOP UNTIL READY
	MOV	A,C	;GET THE BYTE
	OUT	DATA	;SEND IT
	IN	9	;INPUT FROM SENSE
	ANI	01	;CHECK ECHO BIT
	RZ		;DO NOT ECHO
	CALL	PRINT	;ECHO CHAR
	RET
MNUM:	DB	0DH,0AH
	DB	'NUMBER ?'
	DB	0DH,0AH,0
NOASW:	DB 	0DH,0AH
	DB	'NO ANSWER---'
	DB	0
TERM:	DB	0DH,0AH
	DB	'CALL TERMINATED'
	DB	0DH,0AH,0
MDIAL:	DB	0DH,0AH
	DB	'DIALING-'
	DB	0
LOSTC:	DB	0DH,0AH
	DB	'LOST CARRIER'
	DB	0
MEOT:	DB	0DH,0AH
	DB	'EOT'
	DB	0
SIGN:	DB	0DH,0AH
	DB 	'80/103 CONTROL PROGRAM'
	DB	0DH,0AH
	DB	0DH,0AH
	DB	'WAITING FOR RING OR CONTROL B'
	DB	0DH,0AH
	DB	0
ANSBK:	DB	20,20,0DH,20,20,0AH
	DB	'THE STARK COMPUTER NETWORK'
	DB	20,20,0DH,0AH,0
EOSMSG:	DB	13,10,07,07,'END OF SAVE AREA'
	DB	07,07,13,10,0
;
;USER ROUTINES
;
;get input byte
USERIN:	
	IN	1
	ANI	7FH
	RET
;
USERST:	IN	0
	ANI	01H
	MVI	A,0
	RNZ
	DCR	A	;00H to FFH, sets flags
	RET
;
;out to console, Data inC
USEROT:	IN	0
	ANI	80H
	JNZ	USEROT
	MOV	A,C
	OUT	01
	RET
;
MDBYTE	DS	1		;MODE BYTE STORAGE LOC.
NMBR:	DS	20		;20 SPACES FOR PHONE #
STKTOP	EQU	$+64H		;STACK HERE
;         DATA AREA 
  
CMSFLG:	DS	1	;FLAG = 1 if CMS
 INCH:    DS     1              ;INPUT CHAR BUFFER (TO CYBER) 
 OUTCH:   DS     1              ;OUTPUT CHAR BUFFER (FROM CYBER)
  
  
 IBUF:    DS     256            ;INPUT BUFFER 
  
;         TEXT BUFFER 
  
 FLAG:    DS     1              ;TEXT SAVE FLAG 
 PTR:     DS     2              ;TEXT BUFFER POINTER
 SIZE:    DS     2              ;TEXT BUFFER SIZE 
 TBUF     EQU    $              ;START OF TEXT BUFFER 
  
          END    LINK