10 FOR I=1 TO 24
12 PRINT
15 NEXT I REM END OF CLEAR SCREEN ROUTING
18 PRINT "              TAX DEPRECIATION SCHEDULE"
19 PRINT
20 CONSOLE REM TURN PRINTER OFF HERE, OUTPUT TO TERMINAL
22 PRINT
30 PRINT"     PURCHASE PRICE" REM INITIAL VALUE ROUNDED OFF TO NEAREST CENT
40 INPUT V
50 LET V=INT(V*100+.5)/100
60 PRINT "    SALVAGE VALUE" REM END VALUE ROUNDED OFF TO NEAREST CENT
70 INPUT S
80 S=INT(S*100+.5)/100
90 D=V-S REM COMPUTE AMOUNT TO DEPRECIATE
100 PRINT"LIFE IN YEARS" REM LENGTH OF DEPRECIATION
110 INPUT Y
120 PRINT"ENTER 1 FOR SUM OF DIGITS METHOD, 2 FOR DECLINING BALANCE METHOD"
130 INPUT X
140 IF X=2 THEN 450
150 IF X<>1 THEN 120
160 R1=0 REM R1 IS THE CUMULATIVE AMOUNT DEPRECIATED
170 N=66 REM LINE PRINT COUNTER
180 PRINT
190 PRINT
192 PRINT"ENTER 1 IF YOU WANT PRINTED OUTPUT, 0 FOR CONSOLE OUTPUT"
193 INPUT A
194 IF A=0 THEN 200
195 IF A<>1 THEN 192
196 LPRINTER REM TURN PRINTER ON HERE
200 FOR I=1 TO Y
210 IF N<55 THEN 330 REM TEST FOR FULL PAGE
220 FOR I1=N TO 66 REM FULL PAGE COUNT, DO TOP OF FORM AND PRINT HEADINGS
230 PRINT
240 NEXT I1
250 N=7
260 PRINT "                SUM OF DIGITS TAX DEPRECIATION"
270 PRINT "			PRICE $";V
280 PRINT "                  SALVAGE VALUE $";S
290 PRINT "                NET DEPRECIATED $";V-S
300 PRINT "                        LIFE";Y;"YEARS"
310 PRINT
320 PRINT "YEAR","DEPRECIATION","BALANCE"
330 R=2*D*(Y-I+1)/((Y+1)*Y)
340 R=INT(R*100+.5)/100
350 R1=R1+R REM ACCUMULATE DEPRECIATION
360 B=D-R1 REM COMPUTE BALANCE TO DEPRECIATE
370 IF B>0 THEN 410 REM TEST FOR COMPLETE DEPRECIATION
380 R1=R1+B
390 R=R+B
400 B=0
410 PRINT I,R,B
420 N=N+1
430 NEXT I
440 GOTO 700
450 PRINT "DECLINING BALANCE METHOD % (e.g. 150%)" 
460 INPUT M
470 M=M/100 REM CONVERT PERCENT TO DECIMAL
472 PRINT"ENTER 1 FOR PRINTER OUTPUT, 0 FOR TERMINAL OUTPUT"
473 INPUT A
474 IF A=0 THEN 480
475 IF A<>1 THEN 472
476 LPRINTER
480 N=66 REM NUMBER OF LINES PER PAGE
490 R=D REM R IS AMOUNT LEFT TO DEPRECIATE
500 PRINT
510 FOR I=1 TO Y
520 IF N<55 THEN 650 REM TEST FOR FULL PRINTED PAGE
530 FOR I1=N TO 66 REM FOR NEXT PAGE AND PRINT HEADINGS
540 PRINT
550 NEXT I1
560 N=8
570 PRINT"	DECLINING BALANCE TAX DEPRECIATION"
580 PRINT"            PRICE $";V
590 PRINT"         SALVAGE VALUE $";S
600 PRINT"       NET DEPRECIATED $";D
610 PRINT"            LIFE";Y;"YEARS"
620 PRINT"            METHOD ";M*100;"%"
630 PRINT
640 PRINT"YEAR","DEPRECIATION","BALANCE"
650 R1=INT((R*M/Y)*100+.5)/100 REM COMPUTES DEPRECIATION ROUNDED TO NEAREST CT
660 R=R-R1
670 PRINT I,R1,R
680 N=N+1
690 NEXT I
700 PRINT
710 PRINT "MORE DATA? (1=YES,0=NO)";
720 INPUT X
730 IF X=1 THEN 20
740 END