100 REM ********************************************************************
200 REM *  This program will print out an enthalpy chart for superheated   *
300 REM *  steam when you input the average temperature (deg. F) and the   *
400 REM *  average pressure (psia) that you would like to print a chart    *
500 REM *  for. The program is designed for use with an Epson MX printer   *
600 REM *  but should work okay with any printer with only a few changes.  *
700 REM *                                                                  *
800 REM *                Written by: Mike Davis                            *
900 REM *                                                                  *
1000 REM *                      Date: 2/3/84                                *
1100 REM ********************************************************************
1200 REM
1300 PRINT CHR$(26) : PRINT : PRINT
1400 INPUT "Enter the average temp.(F) & pressure (PSIA) : ",X,Y
1500 IF X < 62 OR X > 1200 THEN PRINT "  TEMPERATURE OUT OF RANGE!" : GOTO 1400
1600 IF Y < 51 OR Y > 3200 THEN PRINT "  PRESSURE OUT OF RANGE!" : GOTO 1400
1700 X = X-30 : Y = Y-50
1800 LPRINT SPC(25) "Superheated Steam Enthalpy Chart"
1900 LPRINT
2000 LPRINT CHR$(15) ' Sets the MX 100 printer to condensed print mode.
2100 LPRINT SPC(65) "(Degrees Fahrenheit)"
2200 LPRINT SPC(15);
2300 FOR I = X TO X+60 STEP 5
2400 LPRINT USING "   ###   ";I;
2500 NEXT
2600 LPRINT
2700 LPRINT SPC(14);
2800 LPRINT "====================================================================================================================="
2900 FOR P1 = Y TO Y+100 STEP 2
3000 LPRINT SPC(4);
3100 LPRINT USING "#### psia |";P1;
3200 FOR T1 = X TO X+60 STEP 5
3300 GOSUB 3900
3400 LPRINT USING "  ####.# ";HTP;
3500 NEXT T1
3600 LPRINT
3700 NEXT P1
3800 END
3900 T = 255.38 + T1 / 1.8
4000 P = P1 / 14.6959
4100 B1 = (2641.62 * 10^(80870! / (T * T))) / T
4200 B0 = 1.89 - B1
4300 B2 = 82.546
4400 B3 = 162460! / T
4500 B4 = .21828 * T
4600 B5 = 126970! / T
4700 F0 = 1.89 - B1 * (372420! / (T * T) + 2)
4800 B6 = B0 * B3 - 2 * F0 * (B2 - B3)
4900 B7 = 2 * F0 * (B4 - B5) - B0 * B5
5000 B8 = .434294 * LOG(T)
5100 F = 775.596 + (.63296 + .0001624 * T) * T + 47.3635 * B8
5200 B9 = B0 * P * P / (2 * T * T)
5300 HTP = F + .043577 * (F0 * P + B9 * (B0 * (B2 - B3 + 2 * B7 * B9) - B6))
5400 RETURN
5200 B9 = B0 * P * P / (2 * T * T)
5300 H