$! ACCT_MENU.COM
$! 01-Aug-91 L Baldwin
$ GOTO SKIP_CNTRLY
$!----------------------------------------------------------------
$!
$!	Control Y was press if we got to this routine.
$!		Put this here so there is FAST response to ^Y
$!
$!----------------------------------------------------------------
$CNTRLY:
$ TYPE SYS$INPUT:

	Command procedure aborted by Control Y

$ EXIT
$!
$SKIP_CNTRLY:
$!
$!   This is the new MENU command file which will allow the system
$!   manager to do things even if he has never read the manual.
$!
$ ON CONTROL_Y THEN GOTO CNTRLY
$ SAY = "WRITE SYS$OUTPUT"
$ IF .NOT.F$GETDVI("SYS$OUTPUT","TT_ANSICRT") THEN CLS = CRLF+DASHES+CRLF
$ GOTO MENU_NOWAIT
$!
$!   Enter here, if you do not want the text on the screen to disappear
$!
$ MAIN_MENU:
$ SAY ""
$ INQUIRE/NOPUNCT DUMMY "		Press [return] for main menu"
$!
$MENU_NOWAIT:
$ MENU_ENTRIES = 4
$ SAY CLS
$ TYPE SYS$INPUT

		M A N A G E   U S E R S   M E N U

	 1 - RETURN	- Return to previous menu
	 2 - ADDUSER	- Add a new user
	 3 - REMUSER	- Remove an existing user
	 4 - UAFRPT	- Product a report of all existing users

$!
$ INQUIRE/NOPUNCT NUMBER "Enter a number: "
$ IF NUMBER .EQS. "" THEN EXIT
$ N = F$INTEGER(NUMBER)
$ IF ((N.LT.1).OR.(N.GT.MENU_ENTRIES)) THEN GOTO MM_ERROR
$ SAY CLS
$ GOTO DO_'F$STRING(N)'
$!
$!   An incorrect answer has been entered if here.
$!
$ MM_ERROR:
$ TYPE TASM$COM:TASM_MENU_INPERR.MSG
$ GOTO MAIN_MENU
$!--------------------------------------------------------------------
$!
$!   We have received a valid entry
$!
$!--------------------------------------------------------------------
$!
$!
$DO_1:
$ EXIT
$!
$DO_2:
$ @TASM$COM:ACCT_ADDUSER
$ GOTO MAIN_MENU
$!
$DO_3:
$!
$ @TASM$COM:ACCT_REMUSER
$ GOTO MAIN_MENU
$!
$DO_4:
$ @TASM$COM:ACCT_UAFRPT
$ GOTO MAIN_MENU