$! SYSTARTUP_VXX.COM
$!
$ SET NOON			! Disable default error handler
$!
$! Redirect Output to a log file
$!
$ DEFINE SYS$OUTPUT SYS$MANAGER:SYSTARTUP_VXX.LOG
$ DEFINE SYS$ERROR SYS$MANAGER:SYSTARTUP_VXX.LOG
$ SET PREFIX "<!5%T> "		! Enable time-stamps on log file
$ SET VERIFY
$ OPEN/WRITE CONSOLE OPA0:
$ SAY:=CALL DO_OUTPUT		! Send output to logfile and Console
$ SAY "Starting SYSTARTUP_VXX"
$!
$! Start Network Products
$!
$ SAY "	Invoking STARTUP_NETWORK"
$ @SYS$MANAGER:STARTUP_NETWORK
$ SAY "	Completed STARTUP_NETWORK"
$!
$! Configure terminal devices
$!
$ SAY "	Invoking STARTUP_SETTERM"
$ @SYS$COMMON:[SYSMGR]STARTUP_SETTERM.COM
$ SAY "	Completed STARTUP_SETTERM"
$!
$! Start Print/Batch queues
$!
$ SAY "	Invoking STARTUP_QUEUES"
$ @SYS$COMMON:[SYSMGR]STARTUP_QUEUES.COM
$ SAY "	Completed STARTUP_QUEUES"
$!
$! Crash dump analysis (if necessary)
$!
$! SUBMIT/NOPRINT SYS$COMMON:[SYSMGR]STARTUP_SDA.COM
$!
$! Reconfigure images installed by VMSIMAGES.DAT
$! 
$ SAY "	Invoking STARTUP_SHARE"
$ @SYS$COMMON:[SYSMGR]STARTUP_SHARE.COM
$ SAY "	Completed STARTUP_SHARE"
$!
$! Start Layered Products
$!
$ SAY "	Invoking STARTUP_PRODUCTS"
$ @SYS$COMMON:[SYSMGR]STARTUP_PRODUCTS.COM
$ SAY "	Completed STARTUP_PRODUCTS"
$!
$! Start In-house Applications
$!
$ SAY "	Invoking STARTUP_APPLICATIONS"
$ @SYS$COMMON:[SYSMGR]STARTUP_APPLICATIONS.COM
$ SAY "	Completed STARTUP_APPLICATIONS"
$!
$! Define interactive login limit
$!
$ STARTUP$INTERACTIVE_LOGINS == 64
$!
$! Broacast system availability
$!
$ REPLY/ALL/BELL "System ''f$getsyi("NODENAME")' now available."
$!
$!
$! Check for Startup Errors
$!
$ SUBMIT/NOPRINT SYS$MANAGER:STARTUP_CHECK
$!
$! Cleanup and exit
$!
$ SAY "Completed SYSTARTUP_VXX"
$ CLOSE CONSOLE
$ SET NOPREFIX
$ SET NOVERIFY
$ EXIT
$!
$DO_OUTPUT: SUBROUTINE
$ string = f$fao("!/!AS!AS!AS!/","*** ",p1," ***")
$ write console string
$ EXIT