$! SYPAGSWPFILES.COM
$!
$ SET NOON			! Disable default error handler
$!
$! Redirect Output to a log file
$!
$ DEFINE SYS$OUTPUT SYS$MANAGER:SYPAGSWPFILES.LOG
$ DEFINE SYS$ERROR SYS$MANAGER:SYPAGSWPFILES.LOG
$ SET PREFIX "<!5%T> "		! Enable time-stamps on log file
$ SET VERIFY
$ OPEN/WRITE CONSOLE OPA0:
$ SAY:=CALL DO_OUTPUT		! Send output to logfile and Console
$!
$ SAY "Starting SYPAGSWPFILES"
$!
$! Note: all disks are mounted prior to this point, therefore it
$! is not necessary to perform any disk mounts in this procedure
$!
$ SYSGEN:==$SYSGEN
$ NODE=F$EDIT(F$GETSYI("NODENAME"),"COLLAPSE")
$!
$! Page files for node BART
$!
$ IF NODE .EQS. "BART" 
$ THEN
$ 	PAGEFILE2 = "DISK$USER1:[PAGEFILES]PAGEFILE2.SYS"
$ 	SWAPFILE2 = "DISK$USER1:[PAGEFILES]SWAPFILE2.SYS"
$ 	IF F$SEARCH(PAGEFILE2) .NES. "" THEN -
		SYSGEN INSTALL 'PAGEFILE2'/PAGE
$!
$ 	IF F$SEARCH(SWAPFILE2) .NES. "" THEN -
		SYSGEN INSTALL 'SWAPFILE2'/SWAP
$ ENDIF
$!
$! Other Cluster members
$!
$! IF NODE .EQS. "LISA"
$! ...
$!
$!
$! Cleanup and exit
$!
$ SAY "Completed SYPAGSWPFILES"
$ CLOSE CONSOLE
$ SET NOPREFIX
$ SET NOVERIFY
$ EXIT
$!
$DO_OUTPUT: SUBROUTINE
$ string = f$fao("!/!AS!AS!AS!/","*** ",p1," ***")
$ write console string
$ EXIT